リファレンス / 3ds Max / Pencil+ 4 リファレンス

Pencil+ 4 Line Effect リファレンス

更新: 2026年9月17日

• 3ds Max
• MaxScript
• Pencil+ 4

3ds Max 2022 / Pencil+ 4 プロパティ・メソッド一覧
プロパティなどをInspectして少し加筆しました。

1. Pencil__4_Line（renderEffect）

Line Effect 本体。getEffect i で取得。

クラス名の注意
MaxScript上のクラス名は Pencil__4_Line（アンダースコア 2つ）。
「Pencil+ 4 Line」の + と空白がそれぞれ _ に変換されるため。

classOf (getEffect 1)  -- => Pencil__4_Line

プロパティ

インターフェイス: Pcl4Line

2. 環境効果の管理API

Pencil+ 4 Line は 3ds Max の環境効果（Environment Effects）に属する。大気効果（Atmospherics）とは別系統のため、操作APIが異なる。

環境効果（Pencil+ 4 Line が属する側）

大気効果（Fog, Volume Fog 等）

注意: renderers.current はレンダラー（Scanline, V-Ray等）を返すものであり、Pencil+ 4 Line エフェクトは取得できない。必ず getEffect i を使用すること。

効果の収集パターン

-- シーン内の全 Pencil+ 4 Line エフェクトを収集
fn collectPencilLineEffects = (
    local result = #()
    for i = 1 to numEffects do (
        local effect = getEffect i
        if classOf effect == Pencil__4_Line do (
            append result effect
        )
    )
    return result
)

効果の削除パターン

削除時は逆順で行う。順方向で削除するとインデックスがずれる。

-- 条件に一致する環境効果を削除
-- ※逆順で削除しないとインデックスずれが発生する
for i = numEffects to 1 by -1 do (
    local effect = getEffect i
    if classOf effect == Pencil__4_Line do (
        deleteEffect i
    )
)

3. Pencil__4_Line_Set（ReferenceTarget）

effect.linesets[i] で取得。1ラインセットの全設定を保持。

基本プロパティ

.pl4について

テキストで各パラメータの直書きをI/Oするものっぽい

大まかな設定は持っていけるようだが、.ColorMapに紐づいているtextureMapなどは持っていけない。

細かい設定をちゃんと持っていけなさそうなので、使用は非推奨かも…

ラインセットの対象指定方式

ラインセットは マテリアルベース（.mtls）または オブジェクトベース（.objects）のどちらかで描画対象を指定できる。

.mtls にマテリアルが登録されている場合、そのマテリアルが実際にシーン内のオブジェクトに割り当てられているかどうかで、ラインセットが実質的に有効かを判定できる。

-- ラインセットに有効な対象が存在するかチェック
fn isLinesetActive ls sceneMats = (
    local hasMtls = ls.mtls != undefined and ls.mtls.count > 0
    local hasObjects = ls.objects != undefined and ls.objects.count > 0
    
    -- 両方空なら無効
    if not hasMtls and not hasObjects then return false
    
    -- オブジェクトベースなら有効
    if not hasMtls and hasObjects then return true
    
    -- マテリアルベース: シーン内に存在するマテリアルがあるか
    for mat in ls.mtls do (
        if mat != undefined and findItem sceneMats mat > 0 then
            return true
    )
    
    false
)

エッジ表示（Visible ライン）

エッジ表示（Hidden ライン）

個別ブラシ有効化（Visible / Hidden）

命名規則: .specific{EdgeType}Enable{Visible|Hidden}

減衰 有効化

ブラシ設定参照

各エッジタイプに対し Visible 用 / Hidden 用のブラシを持つ。

減衰設定参照

4. Brush_Settings（textureMap）

ブラシ設定。各エッジタイプごとに1インスタンス。

プロパティ

.ColorMapについて

TextureMapを貼り付けるとその色の線が出る。 UVに沿って色が描画されるので、テクスチャごとに色線を分けることは可能。

標準UIからはbitmap内のパラメータは触れないが、設定したbitmapを割り当てたりなどは可能なので、クロッピングなども一応可能。

現状のプロジェクトでは安全性重視で素のbitmapで統一してたりする。

5. Brush_Details（textureMap）

ブラシの詳細パラメータ（ストローク・ノイズ等）。

基本パラメータ

カーブ

ストローク

ノイズ

減衰・カラー範囲

6. Reduction_Settings（textureMap）

サイズ・アルファ減衰の距離設定。

プロパティ

減衰カーブのデフォルト値

ポイント2点: (0.0, 1.0) → (1.0, 0.1) （近→遠で 100%→10%）

オブジェクト基準の減衰

.objectnode にシーン内のオブジェクト（球体等）を割り当てると、カメラからの距離ではなく、そのオブジェクトからの距離でラインの減衰が計算される。口周りや顔の輪郭線などで、特定部位に近い線を細くする用途で使用する。

-- ラインセットの sizeReduction にオブジェクト基準の減衰を設定
local ls = pencilLineEffect.linesets[1]
local sphereObj = getNodeByName "mouthline_sphere"

ls.sizeReduction.objectnode = sphereObj
ls.sizeReduction.objectEnable = true
ls.sizeReduction.start = 10.0    -- 減衰開始距離
ls.sizeReduction.End = 50.0      -- 減衰終了距離

7. Pencil__4_Curve_Control_Interface（ReferenceTarget）

カーブ制御インターフェイス。ブラシ詳細設定・減衰設定のカーブに使用。

プロパティ

インターフェイス: Pcl4CurveControlIF

フラグ値の参考

8. アクセスパス早見表

-- Effect 取得（環境効果から走査）
for i = 1 to numEffects do (
    local e = getEffect i
    if classOf e == Pencil__4_Line do ( /* ... */ )
)

-- エフェクト名
fx = getEffect 1
fx.name                         -- エフェクト名

-- ラインセット
ls = fx.linesets[1]
ls.name                         -- ラインセット名
ls.objects                      -- 対象オブジェクト配列
ls.mtls                         -- 対象マテリアル配列

-- ブラシ（Visible / Hidden）
ls.brush                        -- デフォルトブラシ (Visible)
ls.brush_Hidden                 -- デフォルトブラシ (Hidden)
ls.brushOutline                 -- アウトライン用 (Visible)
ls.brushOutline_Hidden          -- アウトライン用 (Hidden)

-- ブラシ詳細
ls.brush.detail                 -- Brush_Details
ls.brush.detail.size            -- ブラシサイズ
ls.brush.detail.noiseEnable     -- ノイズ有効

-- ブラシのカラー・サイズ（Brush_Settings レベル）
ls.brush.color                  -- (color 0 0 0)
ls.brush.size                   -- 1.0
ls.brush.alpha                  -- 100.0

-- 減衰設定
ls.sizeReduction.start          -- 100.0
ls.sizeReduction.End            -- 1000.0
ls.sizeReduction.objectnode     -- 基準オブジェクト
ls.sizeReduction.objectEnable   -- オブジェクト基準有効

-- カーブ操作
curveIF = ls.brush.detail.sizeCurveIF
curveIF.numPoints               -- ポイント数
curveIF.pointsX                 -- X座標配列
curveIF.pointsY                 -- Y座標配列

-- カーブからY値取得（Pcl4CurveControlIF）
xVals = #(0.0, 0.25, 0.5, 0.75, 1.0)
yVals = curveIF.Pcl4CurveControlIF.getValues &xVals

-- 環境効果の削除（逆順必須）
for i = numEffects to 1 by -1 do (
    local e = getEffect i
    if classOf e == Pencil__4_Line do deleteEffect i
)

9. 注意事項

• クラス名: Pencil__4_Line（アンダースコア2つ）が正式名。Pencil+ の + と空白がそれぞれ _ に変換される。classOf での比較時に注意。
• 環境効果と大気効果の区別: Pencil+ 4 Line は環境効果（getEffect / deleteEffect）に属する。getAtmospheric では取得できない。
• 効果の削除は逆順: deleteEffect はインデックス指定のため、順方向で削除するとインデックスがずれる。必ず numEffects to 1 by -1 のパターンで行う。
• .strokeeExtendRnd は Pencil+ 4 側のtypo（e が二重）。スクリプトでもそのまま使用する。
• ブラシ設定は Visible 用と Hidden 用で別インスタンス。同一オブジェクトの共有ではない。
• Brush_Settings は textureMap を継承しており、マテリアルエディタ上でも扱える。
• カーブのフラグ値（266, 267 等）は Pencil+ 内部のポイントタイプを示す（公式ドキュメント未公開）。
• ラインセットの対象指定: .mtls（マテリアルベース）と .objects（オブジェクトベース）の両方が空の場合、そのラインセットは実質無効。